initial
This commit is contained in:
Viktor Barzin
parent
090766cab0
commit
a33f99e765
1725 changed files with 129819 additions and 0 deletions
60
dot_oh-my-zsh/plugins/nvm/README.md
Normal file
60
dot_oh-my-zsh/plugins/nvm/README.md
Normal file
|
|
@ -0,0 +1,60 @@
|
|||
# nvm plugin
|
||||
|
||||
This plugin adds autocompletions for [nvm](https://github.com/nvm-sh/nvm) — a Node.js version manager. It also
|
||||
automatically sources nvm, so you don't need to do it manually in your `.zshrc`.
|
||||
|
||||
To use it, add `nvm` to the plugins array of your zshrc file:
|
||||
|
||||
```zsh
|
||||
plugins=(... nvm)
|
||||
```
|
||||
|
||||
## Settings
|
||||
|
||||
If you installed nvm in a directory other than `$HOME/.nvm`, set and export `NVM_DIR` to be the directory
|
||||
where you installed nvm.
|
||||
|
||||
These settings should go in your zshrc file, before Oh My Zsh is sourced:
|
||||
|
||||
- **`NVM_HOMEBREW`**: if you installed nvm via Homebrew, in a directory other than `/usr/local/opt/nvm`, you
|
||||
can set `NVM_HOMEBREW` to be the directory where you installed it. For example, on Apple Silicon-based Macs,
|
||||
[Homebrew is installed in `/opt/homebrew`](https://docs.brew.sh/Installation). To get the directory where
|
||||
nvm has been installed, regardless of chip architecture, use `NVM_HOMEBREW=$(brew --prefix nvm)`.
|
||||
|
||||
## Customization
|
||||
|
||||
#### Lazy startup
|
||||
|
||||
This option will help you to defer nvm's load until you use it to speed-up your zsh startup. This will source
|
||||
nvm script only when using it, and will create a function for `node`, `npm`, `pnpm`, `yarn`, and the
|
||||
command(s) specified by `lazy-cmd` option, so when you call either of them, nvm will be loaded and run with
|
||||
default version. To enable it, you can add this snippet to your zshrc, before Oh My Zsh is sourced:
|
||||
|
||||
```zsh
|
||||
zstyle ':omz:plugins:nvm' lazy yes
|
||||
```
|
||||
|
||||
Then, to define extra commands that will also trigger nvm load, you can use a similar syntax, adding as many
|
||||
as you want:
|
||||
|
||||
```zsh
|
||||
zstyle ':omz:plugins:nvm' lazy-cmd eslint prettier typescript ...
|
||||
```
|
||||
|
||||
#### `.nvmrc` autoload
|
||||
|
||||
If set, the plugin will automatically load a node version when if finds a
|
||||
[`.nvmrc` file](https://github.com/nvm-sh/nvm#nvmrc) in the current working directory indicating which node
|
||||
version to load. This can be done, similar as previous options, adding:
|
||||
|
||||
```zsh
|
||||
zstyle ':omz:plugins:nvm' autoload yes
|
||||
```
|
||||
|
||||
To remove the output generated by NVM when autoloading, you can set the following option:
|
||||
|
||||
```zsh
|
||||
zstyle ':omz:plugins:nvm' silent-autoload yes
|
||||
```
|
||||
|
||||
Note: _this will not remove regular `nvm` output_
|
||||
34
dot_oh-my-zsh/plugins/nvm/_nvm
Normal file
34
dot_oh-my-zsh/plugins/nvm/_nvm
Normal file
|
|
@ -0,0 +1,34 @@
|
|||
#compdef nvm
|
||||
#autoload
|
||||
|
||||
[[ -f "$NVM_DIR/nvm.sh" ]] || return 0
|
||||
|
||||
local -a _1st_arguments
|
||||
_1st_arguments=(
|
||||
'help:show help'
|
||||
'--version:print out the latest released version of nvm'
|
||||
'install:download and install a version in <node|iojs|node version number>'
|
||||
'install-latest-npm:download and install the latest npm version'
|
||||
'uninstall:uninstall a version'
|
||||
'use:modify PATH to use <version>. Uses .nvmrc if available'
|
||||
'exec:run <command> on <version>. Uses .nvmrc if available'
|
||||
'run:run `node` on <version> with <args> as arguments. Uses .nvmrc if available'
|
||||
'current:list installed versions'
|
||||
'ls:list installed versions or versions matching a given description'
|
||||
'version:resolve the given description to a single local version'
|
||||
'version-remote:resolve the given description to a single remote version'
|
||||
'ls-remote:list remote versions available for install'
|
||||
'deactivate:undo effects of `nvm` on current shell'
|
||||
'alias:show or set aliases'
|
||||
'unalias:deletes an alias'
|
||||
'reinstall-packages:reinstall global `npm` packages contained in <version> to current version'
|
||||
'unload:unload `nvm` from shell'
|
||||
'which:display path to installed node version. Uses .nvmrc if available'
|
||||
)
|
||||
|
||||
_arguments -C '*:: :->subcmds' && return 0
|
||||
|
||||
if (( CURRENT == 1 )); then
|
||||
_describe -t commands "nvm subcommand" _1st_arguments
|
||||
return
|
||||
fi
|
||||
105
dot_oh-my-zsh/plugins/nvm/nvm.plugin.zsh
Normal file
105
dot_oh-my-zsh/plugins/nvm/nvm.plugin.zsh
Normal file
|
|
@ -0,0 +1,105 @@
|
|||
# See https://github.com/nvm-sh/nvm#installation-and-update
|
||||
if [[ -z "$NVM_DIR" ]]; then
|
||||
if [[ -d "$HOME/.nvm" ]]; then
|
||||
export NVM_DIR="$HOME/.nvm"
|
||||
elif [[ -d "${XDG_CONFIG_HOME:-$HOME/.config}/nvm" ]]; then
|
||||
export NVM_DIR="${XDG_CONFIG_HOME:-$HOME/.config}/nvm"
|
||||
elif (( $+commands[brew] )); then
|
||||
NVM_HOMEBREW="${NVM_HOMEBREW:-${HOMEBREW_PREFIX:-$(brew --prefix)}/opt/nvm}"
|
||||
if [[ -d "$NVM_HOMEBREW" ]]; then
|
||||
export NVM_DIR="$NVM_HOMEBREW"
|
||||
fi
|
||||
fi
|
||||
fi
|
||||
|
||||
# Don't try to load nvm if command already available
|
||||
# Note: nvm is a function so we need to use `which`
|
||||
which nvm &>/dev/null && return
|
||||
|
||||
# TODO: 2022-11-11: Remove soft-deprecate options
|
||||
if (( ${+NVM_LAZY} + ${+NVM_LAZY_CMD} + ${+NVM_AUTOLOAD} )); then
|
||||
# Get list of NVM_* variable settings defined
|
||||
local -a used_vars
|
||||
used_vars=(${(o)parameters[(I)NVM_(AUTOLOAD|LAZY|LAZY_CMD)]})
|
||||
# Nicely print the list in the style `var1, var2 and var3`
|
||||
echo "${fg[yellow]}[nvm plugin] Variable-style settings are deprecated. Instead of ${(j:, :)used_vars[1,-2]}${used_vars[-2]+ and }${used_vars[-1]}, use:\n"
|
||||
if (( $+NVM_AUTOLOAD )); then
|
||||
echo " zstyle ':omz:plugins:nvm' autoload yes"
|
||||
zstyle ':omz:plugins:nvm' autoload yes
|
||||
fi
|
||||
if (( $+NVM_LAZY )); then
|
||||
echo " zstyle ':omz:plugins:nvm' lazy yes"
|
||||
zstyle ':omz:plugins:nvm' lazy yes
|
||||
fi
|
||||
if (( $+NVM_LAZY_CMD )); then
|
||||
echo " zstyle ':omz:plugins:nvm' lazy-cmd $NVM_LAZY_CMD"
|
||||
zstyle ':omz:plugins:nvm' lazy-cmd $NVM_LAZY_CMD
|
||||
fi
|
||||
echo "$reset_color"
|
||||
unset used_vars NVM_AUTOLOAD NVM_LAZY NVM_LAZY_CMD
|
||||
fi
|
||||
|
||||
if zstyle -t ':omz:plugins:nvm' lazy; then
|
||||
# Call nvm when first using nvm, node, npm, pnpm, yarn or other commands in lazy-cmd
|
||||
zstyle -a ':omz:plugins:nvm' lazy-cmd nvm_lazy_cmd
|
||||
eval "
|
||||
function nvm node npm pnpm yarn $nvm_lazy_cmd {
|
||||
unfunction nvm node npm pnpm yarn $nvm_lazy_cmd
|
||||
# Load nvm if it exists in \$NVM_DIR
|
||||
[[ -f \"\$NVM_DIR/nvm.sh\" ]] && source \"\$NVM_DIR/nvm.sh\"
|
||||
\"\$0\" \"\$@\"
|
||||
}
|
||||
"
|
||||
unset nvm_lazy_cmd
|
||||
elif [[ -f "$NVM_DIR/nvm.sh" ]]; then
|
||||
# Load nvm if it exists in $NVM_DIR
|
||||
source "$NVM_DIR/nvm.sh"
|
||||
else
|
||||
return
|
||||
fi
|
||||
|
||||
# Autoload nvm when finding a .nvmrc file in the current directory
|
||||
# Adapted from: https://github.com/nvm-sh/nvm#zsh
|
||||
if zstyle -t ':omz:plugins:nvm' autoload; then
|
||||
function load-nvmrc {
|
||||
local node_version="$(nvm version)"
|
||||
local nvmrc_path="$(nvm_find_nvmrc)"
|
||||
local nvm_silent=""
|
||||
zstyle -t ':omz:plugins:nvm' silent-autoload && nvm_silent="--silent"
|
||||
|
||||
if [[ -n "$nvmrc_path" ]]; then
|
||||
local nvmrc_node_version=$(nvm version $(cat "$nvmrc_path" | tr -dc '[:print:]'))
|
||||
|
||||
if [[ "$nvmrc_node_version" = "N/A" ]]; then
|
||||
nvm install
|
||||
elif [[ "$nvmrc_node_version" != "$node_version" ]]; then
|
||||
nvm use $nvm_silent
|
||||
fi
|
||||
elif [[ "$node_version" != "$(nvm version default)" ]]; then
|
||||
if [[ -z $nvm_silent ]]; then
|
||||
echo "Reverting to nvm default version"
|
||||
fi
|
||||
|
||||
nvm use default $nvm_silent
|
||||
fi
|
||||
}
|
||||
|
||||
autoload -U add-zsh-hook
|
||||
add-zsh-hook chpwd load-nvmrc
|
||||
|
||||
load-nvmrc
|
||||
fi
|
||||
|
||||
# Load nvm bash completion
|
||||
for nvm_completion in "$NVM_DIR/bash_completion" "$NVM_HOMEBREW/etc/bash_completion.d/nvm"; do
|
||||
if [[ -f "$nvm_completion" ]]; then
|
||||
# Load bashcompinit
|
||||
autoload -U +X bashcompinit && bashcompinit
|
||||
# Bypass compinit call in nvm bash completion script. See:
|
||||
# https://github.com/nvm-sh/nvm/blob/4436638/bash_completion#L86-L93
|
||||
ZSH_VERSION= source "$nvm_completion"
|
||||
break
|
||||
fi
|
||||
done
|
||||
|
||||
unset NVM_HOMEBREW nvm_completion
|
||||
Loading…
Add table
Add a link
Reference in a new issue