extract dbaas, authentik, crowdsec from platform into independent stacks [ci skip]

Phase 1 of platform stack split for parallel CI applies.
All 3 modules were fully independent (no cross-module refs).
State migrated via terraform state mv. All 3 stacks applied
with zero changes (dbaas had pre-existing ResourceQuota drift).
Woodpecker pipeline updated to run extracted stacks in parallel.

stacks/authentik/modules/authentik/main.tf

@@ -0,0 +1,88 @@
+variable "tls_secret_name" {}
+variable "secret_key" {}
+variable "postgres_password" {}
+variable "tier" { type = string }
+variable "redis_host" { type = string }
+variable "homepage_token" {
+  type      = string
+  default   = ""
+  sensitive = true
+}
+
+
+module "tls_secret" {
+  source          = "../../../../modules/kubernetes/setup_tls_secret"
+  namespace       = kubernetes_namespace.authentik.metadata[0].name
+  tls_secret_name = var.tls_secret_name
+}
+
+resource "kubernetes_namespace" "authentik" {
+  metadata {
+    name = "authentik"
+    labels = {
+      tier                               = var.tier
+      "resource-governance/custom-quota" = "true"
+    }
+  }
+}
+
+resource "kubernetes_resource_quota" "authentik" {
+  metadata {
+    name      = "authentik-quota"
+    namespace = kubernetes_namespace.authentik.metadata[0].name
+  }
+  spec {
+    hard = {
+      "requests.cpu"    = "16"
+      "requests.memory" = "16Gi"
+      "limits.memory"   = "96Gi"
+      pods              = "50"
+    }
+  }
+}
+
+resource "helm_release" "authentik" {
+  namespace        = kubernetes_namespace.authentik.metadata[0].name
+  create_namespace = true
+  name             = "goauthentik"
+
+  repository = "https://charts.goauthentik.io/"
+  chart      = "authentik"
+  # version    = "2025.8.1"
+  version = "2025.10.3"
+  atomic  = true
+  timeout = 6000
+
+  values = [templatefile("${path.module}/values.yaml", { postgres_password = var.postgres_password, secret_key = var.secret_key, redis_host = var.redis_host })]
+}
+
+
+module "ingress" {
+  source          = "../../../../modules/kubernetes/ingress_factory"
+  namespace       = kubernetes_namespace.authentik.metadata[0].name
+  name            = "authentik"
+  service_name    = "goauthentik-server"
+  tls_secret_name = var.tls_secret_name
+  extra_annotations = {
+    "gethomepage.dev/enabled"      = "true"
+    "gethomepage.dev/name"         = "Authentik"
+    "gethomepage.dev/description"  = "Identity provider"
+    "gethomepage.dev/icon"         = "authentik.png"
+    "gethomepage.dev/group"        = "Identity & Security"
+    "gethomepage.dev/pod-selector" = ""
+    "gethomepage.dev/widget.type"  = "authentik"
+    "gethomepage.dev/widget.url"   = "http://goauthentik-server.authentik.svc.cluster.local"
+    "gethomepage.dev/widget.key"   = var.homepage_token
+  }
+}
+
+module "ingress-outpost" {
+  source          = "../../../../modules/kubernetes/ingress_factory"
+  namespace       = kubernetes_namespace.authentik.metadata[0].name
+  name            = "authentik-outpost"
+  host            = "authentik"
+  service_name    = "ak-outpost-authentik-embedded-outpost"
+  port            = 9000
+  ingress_path    = ["/outpost.goauthentik.io"]
+  tls_secret_name = var.tls_secret_name
+}

stacks/authentik/modules/authentik/pgbouncer.ini

@@ -0,0 +1,14 @@
+[databases]
+authentik = host=postgresql.dbaas port=5432 dbname=authentik user=authentik password=${password}
+
+[pgbouncer]
+listen_addr = 0.0.0.0
+listen_port = 6432
+auth_type = md5
+auth_file = /etc/pgbouncer/userlist.txt
+pool_mode = transaction
+max_client_conn = 200
+default_pool_size = 20
+reserve_pool_size = 5
+reserve_pool_timeout = 5
+ignore_startup_parameters = extra_float_digits

stacks/authentik/modules/authentik/pgbouncer.tf

@@ -0,0 +1,140 @@
+resource "kubernetes_config_map" "pgbouncer_config" {
+  metadata {
+    name      = "pgbouncer-config"
+    namespace = "authentik"
+  }
+
+  data = {
+    "pgbouncer.ini" = templatefile("${path.module}/pgbouncer.ini", { password = var.postgres_password })
+  }
+}
+
+# --- 2️⃣ Secret for user credentials ---
+resource "kubernetes_secret" "pgbouncer_auth" {
+  metadata {
+    name      = "pgbouncer-auth"
+    namespace = "authentik"
+  }
+
+  data = {
+    "userlist.txt" = templatefile("${path.module}/userlist.txt", { password = var.postgres_password })
+  }
+
+  type = "Opaque"
+}
+
+# --- 3️⃣ Deployment ---
+resource "kubernetes_deployment" "pgbouncer" {
+  metadata {
+    name      = "pgbouncer"
+    namespace = "authentik"
+    labels = {
+      app  = "pgbouncer"
+      tier = var.tier
+    }
+  }
+
+  spec {
+    replicas = 3
+
+    selector {
+      match_labels = {
+        app = "pgbouncer"
+      }
+    }
+
+    template {
+      metadata {
+        labels = {
+          app = "pgbouncer"
+        }
+      }
+
+      spec {
+        affinity {
+          pod_anti_affinity {
+            required_during_scheduling_ignored_during_execution {
+              label_selector {
+                match_expressions {
+                  key      = "component"
+                  operator = "In"
+                  values   = ["server"]
+                }
+              }
+              topology_key = "kubernetes.io/hostname"
+            }
+          }
+        }
+        container {
+          name              = "pgbouncer"
+          image             = "edoburu/pgbouncer:latest"
+          image_pull_policy = "IfNotPresent"
+
+          port {
+            container_port = 6432
+          }
+
+          volume_mount {
+            name       = "config"
+            mount_path = "/etc/pgbouncer/pgbouncer.ini"
+            sub_path   = "pgbouncer.ini"
+          }
+
+          volume_mount {
+            name       = "auth"
+            mount_path = "/etc/pgbouncer/userlist.txt"
+            sub_path   = "userlist.txt"
+          }
+
+          env {
+            name  = "DATABASES_AUTHENTIK"
+            value = "host=postgres port=5432 dbname=authentik user=authentik password=${var.postgres_password}"
+          }
+        }
+
+        volume {
+          name = "config"
+          config_map {
+            name = kubernetes_config_map.pgbouncer_config.metadata[0].name
+          }
+        }
+
+        volume {
+          name = "auth"
+          secret {
+            secret_name = kubernetes_secret.pgbouncer_auth.metadata[0].name
+          }
+        }
+        dns_config {
+          option {
+            name  = "ndots"
+            value = "2"
+          }
+        }
+      }
+    }
+  }
+  depends_on = [kubernetes_secret.pgbouncer_auth]
+}
+
+# --- 4️⃣ Service ---
+resource "kubernetes_service" "pgbouncer" {
+  metadata {
+    name      = "pgbouncer"
+    namespace = "authentik"
+  }
+
+  spec {
+    selector = {
+      app = "pgbouncer"
+    }
+
+    port {
+      port        = 6432
+      target_port = 6432
+      protocol    = "TCP"
+    }
+
+    type = "ClusterIP"
+  }
+}

stacks/authentik/modules/authentik/userlist.txt

@@ -0,0 +1 @@
+"authentik" "${password}"

stacks/authentik/modules/authentik/values.yaml

@@ -0,0 +1,73 @@
+authentik:
+  log_level: warning
+  # log_level: trace
+  secret_key: "${secret_key}"
+  # This sends anonymous usage-data, stack traces on errors and
+  # performance data to authentik.error-reporting.a7k.io, and is fully opt-in
+  error_reporting:
+    enabled: true
+  postgresql:
+    # host: postgresql.dbaas
+    host: pgbouncer.authentik
+    port: 6432
+    user: authentik
+    password: ${postgres_password}
+  redis:
+    host: ${redis_host}
+
+server:
+  replicas: 3
+  strategy:
+    type: RollingUpdate
+    rollingUpdate:
+      maxSurge: 0
+      maxUnavailable: 1
+  resources:
+    requests:
+      cpu: 100m
+      memory: 1Gi
+    limits:
+      memory: 1Gi
+  topologySpreadConstraints:
+    - maxSkew: 1
+      topologyKey: kubernetes.io/hostname
+      whenUnsatisfiable: ScheduleAnyway
+      labelSelector:
+        matchLabels:
+          app.kubernetes.io/component: server
+  ingress:
+    enabled: false
+    # hosts:
+    #   - authentik.viktorbarzin.me
+  podAnnotations:
+    diun.enable: true
+    diun.include_tags: "^202[0-9].[0-9]+.*$" # no need to annotate the worker as it uses the same image
+  pdb:
+    enabled: true
+    minAvailable: 2
+global:
+  addPrometheusAnnotations: true
+
+worker:
+  replicas: 3
+  strategy:
+    type: RollingUpdate
+    rollingUpdate:
+      maxSurge: 0
+      maxUnavailable: 1
+  resources:
+    requests:
+      cpu: 100m
+      memory: 896Mi
+    limits:
+      memory: 896Mi
+  topologySpreadConstraints:
+    - maxSkew: 1
+      topologyKey: kubernetes.io/hostname
+      whenUnsatisfiable: ScheduleAnyway
+      labelSelector:
+        matchLabels:
+          app.kubernetes.io/component: worker
+  pdb:
+    enabled: true
+    maxUnavailable: 1