extract remaining 19 modules from platform, complete stack split [ci skip]

Phase 3: all 27 platform modules now run as independent stacks.
Platform reduced to empty shell (outputs only) for backward compat
with 72 app stacks that declare dependency "platform".
Fixed technitium cross-module dashboard reference by copying file.
Woodpecker pipeline applies all 27+1 stacks in parallel via loop.
All applied with zero destroys.

stacks/nfs-csi/modules/nfs-csi/main.tf

@@ -0,0 +1,90 @@
+variable "tier" { type = string }
+variable "nfs_server" { type = string }
+
+resource "kubernetes_namespace" "nfs_csi" {
+  metadata {
+    name = "nfs-csi"
+    labels = {
+      tier = var.tier
+    }
+  }
+}
+
+resource "helm_release" "nfs_csi_driver" {
+  namespace        = kubernetes_namespace.nfs_csi.metadata[0].name
+  create_namespace = false
+  name             = "csi-driver-nfs"
+  atomic           = true
+  timeout          = 300
+
+  repository = "https://raw.githubusercontent.com/kubernetes-csi/csi-driver-nfs/master/charts"
+  chart      = "csi-driver-nfs"
+
+  values = [yamlencode({
+    controller = {
+      replicas = 2
+      resources = {
+        csiProvisioner = {
+          requests = { cpu = "10m", memory = "128Mi" }
+          limits   = { memory = "128Mi" }
+        }
+        csiResizer = {
+          requests = { cpu = "10m", memory = "128Mi" }
+          limits   = { memory = "128Mi" }
+        }
+        csiSnapshotter = {
+          requests = { cpu = "10m", memory = "128Mi" }
+          limits   = { memory = "128Mi" }
+        }
+        nfs = {
+          requests = { cpu = "10m", memory = "128Mi" }
+          limits   = { memory = "128Mi" }
+        }
+        livenessProbe = {
+          requests = { cpu = "10m", memory = "64Mi" }
+          limits   = { memory = "64Mi" }
+        }
+      }
+    }
+    node = {
+      resources = {
+        nfs = {
+          requests = { cpu = "10m", memory = "128Mi" }
+          limits   = { memory = "128Mi" }
+        }
+        livenessProbe = {
+          requests = { cpu = "10m", memory = "64Mi" }
+          limits   = { memory = "64Mi" }
+        }
+        nodeDriverRegistrar = {
+          requests = { cpu = "10m", memory = "64Mi" }
+          limits   = { memory = "64Mi" }
+        }
+      }
+    }
+    storageClass = {
+      create = false
+    }
+  })]
+}
+
+resource "kubernetes_storage_class" "nfs_truenas" {
+  metadata {
+    name = "nfs-truenas"
+  }
+  storage_provisioner = "nfs.csi.k8s.io"
+  reclaim_policy      = "Retain"
+  volume_binding_mode = "Immediate"
+
+  mount_options = [
+    "soft",
+    "timeo=30",
+    "retrans=3",
+    "actimeo=5",
+  ]
+
+  parameters = {
+    server = var.nfs_server
+    share  = "/mnt/main"
+  }
+}