[ci skip] Move Terraform modules into stack directories

Move all 88 service modules (66 individual + 22 platform) from
modules/kubernetes/<service>/ into their corresponding stack directories:

- Service stacks: stacks/<service>/module/
- Platform stack: stacks/platform/modules/<service>/

This collocates module source code with its Terragrunt definition.
Only shared utility modules remain in modules/kubernetes/:
ingress_factory, setup_tls_secret, dockerhub_secret, oauth-proxy.

All cross-references to shared modules updated to use correct
relative paths. Verified with terragrunt run --all -- plan:
0 adds, 0 destroys across all 68 stacks.

stacks/nextcloud/.terraform.lock.hcl

@@ -0,0 +1,40 @@
+# This file is maintained automatically by "terraform init".
+# Manual edits may be lost in future updates.
+
+provider "registry.terraform.io/hashicorp/helm" {
+  version = "3.1.1"
+  hashes = [
+    "h1:47CqNwkxctJtL/N/JuEj+8QMg8mRNI/NWeKO5/ydfZU=",
+    "zh:1a6d5ce931708aec29d1f3d9e360c2a0c35ba5a54d03eeaff0ce3ca597cd0275",
+    "zh:3411919ba2a5941801e677f0fea08bdd0ae22ba3c9ce3309f55554699e06524a",
+    "zh:81b36138b8f2320dc7f877b50f9e38f4bc614affe68de885d322629dd0d16a29",
+    "zh:95a2a0a497a6082ee06f95b38bd0f0d6924a65722892a856cfd914c0d117f104",
+    "zh:9d3e78c2d1bb46508b972210ad706dd8c8b106f8b206ecf096cd211c54f46990",
+    "zh:a79139abf687387a6efdbbb04289a0a8e7eaca2bd91cdc0ce68ea4f3286c2c34",
+    "zh:aaa8784be125fbd50c48d84d6e171d3fb6ef84a221dbc5165c067ce05faab4c8",
+    "zh:afecd301f469975c9d8f350cc482fe656e082b6ab0f677d1a816c3c615837cc1",
+    "zh:c54c22b18d48ff9053d899d178d9ffef7d9d19785d9bf310a07d648b7aac075b",
+    "zh:db2eefd55aea48e73384a555c72bac3f7d428e24147bedb64e1a039398e5b903",
+    "zh:ee61666a233533fd2be971091cecc01650561f1585783c381b6f6e8a390198a4",
+    "zh:f569b65999264a9416862bca5cd2a6177d94ccb0424f3a4ef424428912b9cb3c",
+  ]
+}
+
+provider "registry.terraform.io/hashicorp/kubernetes" {
+  version = "3.0.1"
+  hashes = [
+    "h1:P0c8knzZnouTNFIRij8IS7+pqd0OKaFDYX0j4GRsiqo=",
+    "zh:02d55b0b2238fd17ffa12d5464593864e80f402b90b31f6e1bd02249b9727281",
+    "zh:20b93a51bfeed82682b3c12f09bac3031f5bdb4977c47c97a042e4df4fb2f9ba",
+    "zh:6e14486ecfaee38c09ccf33d4fdaf791409f90795c1b66e026c226fad8bc03c7",
+    "zh:8d0656ff422df94575668e32c310980193fccb1c28117e5c78dd2d4050a760a6",
+    "zh:9795119b30ec0c1baa99a79abace56ac850b6e6fbce60e7f6067792f6eb4b5f4",
+    "zh:b388c87acc40f6bd9620f4e23f01f3c7b41d9b88a68d5255dec0a72f0bdec249",
+    "zh:b59abd0a980649c2f97f172392f080eaeb18e486b603f83bf95f5d93aeccc090",
+    "zh:ba6e3060fddf4a022087d8f09e38aa0001c705f21170c2ded3d1c26c12f70d97",
+    "zh:c12626d044b1d5501cf95ca78cbe507c13ad1dd9f12d4736df66eb8e5f336eb8",
+    "zh:c55203240d50f4cdeb3df1e1760630d677679f5b1a6ffd9eba23662a4ad05119",
+    "zh:ea206a5a32d6e0d6e32f1849ad703da9a28355d9c516282a8458b5cf1502b2a1",
+    "zh:f569b65999264a9416862bca5cd2a6177d94ccb0424f3a4ef424428912b9cb3c",
+  ]
+}

stacks/nextcloud/backend.tf

@@ -0,0 +1,6 @@
+# Generated by Terragrunt. Sig: nIlQXj57tbuaRZEa
+terraform {
+  backend "local" {
+    path = "/Users/viktorbarzin/code/infra/state/stacks/nextcloud/terraform.tfstate"
+  }
+}

stacks/nextcloud/main.tf

@@ -12,7 +12,7 @@ locals {
 }
 
 module "nextcloud" {
-  source = "../../modules/kubernetes/nextcloud"
+  source = "./module"
   tls_secret_name                = var.tls_secret_name
   db_password                    = var.nextcloud_db_password
   tier                           = local.tiers.edge

stacks/nextcloud/module/chart_values.yaml

@@ -0,0 +1,65 @@
+nextcloud:
+  host: nextcloud.viktorbarzin.me
+  trustedDomains:
+    - nextcloud.viktorbarzin.me
+  # mail:
+  #   enabled: true
+  #   # the user we send email as
+  #   fromAddress: nextcloud@viktorbarzin.me
+  #   # the domain we send email from
+  #   domain: viktorbarzin.me
+  #   smtp:
+  #     host: mail.viktorbarzin.me
+  #     secure: starttls
+  #     port: 587
+  #     authtype: LOGIN
+  #     name: nextcloud@viktorbarzin.me
+  #     password:
+  extraEnv:
+    - name: TRUSTED_PROXIES
+      value: "10.0.0.0/8"
+    # - name: mail_smtpdebug
+    #   value: "true"
+    # - name: loglevel
+    #   value: "0"
+
+# internalDatabase:
+#   enabled: false
+
+externalRedis:
+  enabled: true
+  host: redis.redis.svc.cluster.local
+
+# Currently not in use; we use the nextcloud.db sqlite3
+externalDatabase:
+  enabled: false
+  type: mysql
+  host: mysql.dbaas.svc.cluster.local
+  user: nextcloud
+  password: ${db_password}
+  databse: nextcloud
+
+persistence:
+  enabled: true
+  existingClaim: nextcloud-data-pvc
+
+  accessMode: ReadWriteOnce
+  size: 100Gi
+
+startupProbe:
+  enabled: true
+  initialDelaySeconds: 10
+  periodSeconds: 10
+  timeoutSeconds: 5
+  failureThreshold: 30
+  successThreshold: 1
+
+podAnnotations:
+  diun.enable: "true"
+  diun.include_tags: "^[0-9]+(?:.[0-9]+)?(?:.[0-9]+)?.*"
+
+collabora:
+  enabled: false # Using onlyoffice instead
+
+cronjob:
+  enabled: true

stacks/nextcloud/module/main.tf

@@ -0,0 +1,317 @@
+variable "tls_secret_name" {}
+variable "db_password" {}
+variable "tier" { type = string }
+
+module "tls_secret" {
+  source          = "../../../modules/kubernetes/setup_tls_secret"
+  namespace       = kubernetes_namespace.nextcloud.metadata[0].name
+  tls_secret_name = var.tls_secret_name
+}
+
+resource "kubernetes_namespace" "nextcloud" {
+  metadata {
+    name = "nextcloud"
+    labels = {
+      "istio-injection" : "disabled"
+      tier = var.tier
+    }
+  }
+}
+
+resource "helm_release" "nextcloud" {
+  namespace = kubernetes_namespace.nextcloud.metadata[0].name
+  name      = "nextcloud"
+
+  repository = "https://nextcloud.github.io/helm/"
+  chart      = "nextcloud"
+  atomic     = true
+  version    = "8.8.1"
+
+  values  = [templatefile("${path.module}/chart_values.yaml", { tls_secret_name = var.tls_secret_name, db_password = var.db_password })]
+  timeout = 6000
+}
+
+# resource "kubernetes_config_map" "config" {
+#   metadata {
+#     name      = "config"
+#    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+
+#     annotations = {
+#       "reloader.stakater.com/match" = "true"
+#     }
+#   }
+
+#   data = {
+#     "conf.yml" = file("${path.module}/conf.yml")
+#   }
+# }
+
+resource "kubernetes_deployment" "whiteboard" {
+  metadata {
+    name      = "whiteboard"
+    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+    labels = {
+      app  = "whiteboard"
+      tier = var.tier
+    }
+    annotations = {
+      "reloader.stakater.com/search" = "true"
+    }
+  }
+  spec {
+    replicas = 1
+    selector {
+      match_labels = {
+        app = "whiteboard"
+      }
+    }
+    template {
+      metadata {
+        labels = {
+          app = "whiteboard"
+        }
+      }
+      spec {
+        priority_class_name = "tier-3-edge"
+        container {
+          image = "ghcr.io/nextcloud-releases/whiteboard:release"
+          name  = "whiteboard"
+
+          port {
+            container_port = 3002
+          }
+          env {
+            name  = "NEXTCLOUD_URL"
+            value = "http://nextcloud:8080"
+          }
+          env {
+            name  = "JWT_SECRET_KEY"
+            value = var.db_password # anything secret is fine
+          }
+        }
+      }
+    }
+  }
+}
+
+resource "kubernetes_service" "whiteboard" {
+  metadata {
+    name      = "whiteboard"
+    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+    labels = {
+      app = "whiteboard"
+    }
+  }
+
+  spec {
+    selector = {
+      app = "whiteboard"
+    }
+    port {
+      name        = "http"
+      port        = 80
+      target_port = 3002
+    }
+  }
+}
+
+resource "kubernetes_persistent_volume" "nextcloud-data-pv" {
+  metadata {
+    name = "nextcloud-data-pv"
+  }
+  spec {
+    capacity = {
+      "storage" = "100Gi"
+    }
+    access_modes = ["ReadWriteOnce"]
+    persistent_volume_source {
+      nfs {
+        path   = "/mnt/main/nextcloud"
+        server = "10.0.10.15"
+      }
+    }
+  }
+}
+
+resource "kubernetes_persistent_volume_claim" "nextcloud-data-pvc" {
+  metadata {
+    name      = "nextcloud-data-pvc"
+    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+  }
+  spec {
+    access_modes = ["ReadWriteOnce"]
+    resources {
+      requests = {
+        "storage" = "100Gi"
+      }
+    }
+    volume_name = "nextcloud-data-pv"
+  }
+}
+
+module "ingress" {
+  source          = "../../../modules/kubernetes/ingress_factory"
+  namespace       = kubernetes_namespace.nextcloud.metadata[0].name
+  name            = "nextcloud"
+  tls_secret_name = var.tls_secret_name
+  port            = 8080
+  rybbit_site_id  = "5a3bfe59a3fe"
+}
+
+module "whiteboard_ingress" {
+  source          = "../../../modules/kubernetes/ingress_factory"
+  namespace       = kubernetes_namespace.nextcloud.metadata[0].name
+  name            = "whiteboard"
+  tls_secret_name = var.tls_secret_name
+  port            = 80
+}
+
+resource "kubernetes_config_map" "backup-script" {
+  metadata {
+    name      = "nextcloud-backup-script"
+    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+  }
+
+  data = {
+    "backup.sh" = <<-EOF
+      #!/bin/bash
+      set -e
+
+      BACKUP_DIR="/backup"
+      DATA_DIR="/nextcloud-data"
+      DATE=$(date +%Y%m%d_%H%M%S)
+      BACKUP_PATH="$BACKUP_DIR/$DATE"
+
+      echo "Starting Nextcloud backup at $(date)"
+
+      # Note: Maintenance mode is skipped because occ is not available in the NFS mount.
+      # For a proper backup with maintenance mode, exec into the nextcloud pod:
+      #   kubectl exec -n nextcloud deployment/nextcloud -- php occ maintenance:mode --on
+
+      # Create backup directory
+      mkdir -p "$BACKUP_PATH"
+
+      # Backup everything (config, data, custom_apps, themes, etc.)
+      echo "Backing up Nextcloud installation..."
+      rsync -a "$DATA_DIR/" "$BACKUP_PATH/"
+
+      # Keep only last 7 backups
+      echo "Cleaning old backups..."
+      cd "$BACKUP_DIR"
+      ls -dt */ | tail -n +8 | xargs -r rm -rf
+
+      echo "Backup completed at $(date)"
+      echo "Backup stored at: $BACKUP_PATH"
+    EOF
+
+    "restore.sh" = <<-EOF
+      #!/bin/bash
+      # Restore script - run manually when needed
+      # Usage: ./restore.sh <backup_date>
+      # Example: ./restore.sh 20250117_030000
+      #
+      # Before restoring, enable maintenance mode:
+      #   kubectl exec -n nextcloud deployment/nextcloud -- php occ maintenance:mode --on
+      # After restoring, disable it:
+      #   kubectl exec -n nextcloud deployment/nextcloud -- php occ maintenance:mode --off
+
+      set -e
+
+      if [ -z "$1" ]; then
+        echo "Usage: $0 <backup_date>"
+        echo "Available backups:"
+        ls -1 /backup/
+        exit 1
+      fi
+
+      BACKUP_PATH="/backup/$1"
+      DATA_DIR="/nextcloud-data"
+
+      if [ ! -d "$BACKUP_PATH" ]; then
+        echo "Backup not found: $BACKUP_PATH"
+        exit 1
+      fi
+
+      echo "Restoring from $BACKUP_PATH"
+
+      # Restore everything
+      echo "Restoring Nextcloud installation..."
+      rsync -a "$BACKUP_PATH/" "$DATA_DIR/"
+
+      echo "Restore completed!"
+      echo "Remember to run: kubectl exec -n nextcloud deployment/nextcloud -- php occ maintenance:mode --off"
+    EOF
+  }
+}
+
+resource "kubernetes_cron_job_v1" "nextcloud-backup" {
+  metadata {
+    name      = "nextcloud-backup"
+    namespace = kubernetes_namespace.nextcloud.metadata[0].name
+  }
+
+  spec {
+    schedule                      = "0 3 * * 0" # Sunday at 3 AM
+    successful_jobs_history_limit = 3
+    failed_jobs_history_limit     = 3
+    concurrency_policy            = "Forbid"
+
+    job_template {
+      metadata {}
+      spec {
+        template {
+          metadata {}
+          spec {
+            restart_policy = "OnFailure"
+
+            container {
+              name  = "backup"
+              image = "alpine:latest"
+
+              command = ["/bin/sh", "-c", "apk add --no-cache rsync bash && /scripts/backup.sh"]
+
+              volume_mount {
+                name       = "nextcloud-data"
+                mount_path = "/nextcloud-data"
+              }
+
+              volume_mount {
+                name       = "backup"
+                mount_path = "/backup"
+              }
+
+              volume_mount {
+                name       = "scripts"
+                mount_path = "/scripts"
+              }
+            }
+
+            volume {
+              name = "nextcloud-data"
+              nfs {
+                server = "10.0.10.15"
+                path   = "/mnt/main/nextcloud"
+              }
+            }
+
+            volume {
+              name = "backup"
+              nfs {
+                server = "10.0.10.15"
+                path   = "/mnt/main/nextcloud-backup"
+              }
+            }
+
+            volume {
+              name = "scripts"
+              config_map {
+                name         = kubernetes_config_map.backup-script.metadata[0].name
+                default_mode = "0755"
+              }
+            }
+          }
+        }
+      }
+    }
+  }
+}

stacks/nextcloud/providers.tf

@@ -0,0 +1,15 @@
+# Generated by Terragrunt. Sig: nIlQXj57tbuaRZEa
+variable "kube_config_path" {
+  type    = string
+  default = "~/.kube/config"
+}
+
+provider "kubernetes" {
+  config_path = var.kube_config_path
+}
+
+provider "helm" {
+  kubernetes = {
+    config_path = var.kube_config_path
+  }
+}

stacks/nextcloud/secrets

@@ -0,0 +1 @@
+../../secrets