[ci skip] Move Terraform modules into stack directories

Move all 88 service modules (66 individual + 22 platform) from
modules/kubernetes/<service>/ into their corresponding stack directories:

- Service stacks: stacks/<service>/module/
- Platform stack: stacks/platform/modules/<service>/

This collocates module source code with its Terragrunt definition.
Only shared utility modules remain in modules/kubernetes/:
ingress_factory, setup_tls_secret, dockerhub_secret, oauth-proxy.

All cross-references to shared modules updated to use correct
relative paths. Verified with terragrunt run --all -- plan:
0 adds, 0 destroys across all 68 stacks.

stacks/wealthfolio/module/main.tf

@@ -0,0 +1,130 @@
+# To refresh transactions use finance db positions exporters:
+#
+# workon finace-app && cd ~/code/finance && python main.py fetch position --imap-user=$IMAP_USER --imap-password=$IMAP_PASSWORD --trading212-api-keys=$TRADING212_API_KEYS --output-file positions.csv && mv positions.csv /home/wizard/code/infra/modules/kubernetes/wealthfolio/updated_trades.csv
+#
+# Then upload updated_trades.csv
+# Note that currently wealthfolio doesn't dedup (https://github.com/afadil/wealthfolio/issues/476)
+
+variable "tls_secret_name" {}
+variable "tier" { type = string }
+variable "wealthfolio_password_hash" {}
+
+resource "kubernetes_namespace" "wealthfolio" {
+  metadata {
+    name = "wealthfolio"
+    labels = {
+      "istio-injection" : "disabled"
+      tier = var.tier
+    }
+  }
+}
+
+module "tls_secret" {
+  source          = "../../../modules/kubernetes/setup_tls_secret"
+  namespace       = kubernetes_namespace.wealthfolio.metadata[0].name
+  tls_secret_name = var.tls_secret_name
+}
+
+resource "random_string" "random" {
+  length = 32
+  lower  = true
+}
+
+resource "kubernetes_deployment" "wealthfolio" {
+  metadata {
+    name      = "wealthfolio"
+    namespace = kubernetes_namespace.wealthfolio.metadata[0].name
+    labels = {
+      app  = "wealthfolio"
+      tier = var.tier
+    }
+  }
+  spec {
+    replicas = 1
+    selector {
+      match_labels = {
+        app = "wealthfolio"
+      }
+    }
+    template {
+      metadata {
+        labels = {
+          app = "wealthfolio"
+        }
+      }
+      spec {
+        container {
+          image = "afadil/wealthfolio:latest"
+          name  = "wealthfolio"
+          port {
+            container_port = 8080
+          }
+          env {
+            name  = "WF_LISTEN_ADDR"
+            value = "0.0.0.0:8080"
+          }
+          env {
+            name  = "WF_AUTH_PASSWORD_HASH"
+            value = var.wealthfolio_password_hash
+          }
+          env {
+            name  = "WF_DB_PATH"
+            value = "/data/wealthfolio.db"
+          }
+          env {
+            name  = "WF_CORS_ALLOW_ORIGINS"
+            value = "https://authentik.viktorbarzin.me"
+          }
+          env {
+            name  = "WF_AUTH_TOKEN_TTL_MINUTES"
+            value = "10080"
+          }
+          env {
+            name  = "WF_SECRET_KEY"
+            value = random_string.random.result
+          }
+          volume_mount {
+            name       = "data"
+            mount_path = "/data"
+          }
+        }
+        volume {
+          name = "data"
+          nfs {
+            server = "10.0.10.15"
+            path   = "/mnt/main/wealthfolio"
+          }
+        }
+      }
+    }
+  }
+}
+
+resource "kubernetes_service" "wealthfolio" {
+  metadata {
+    name      = "wealthfolio"
+    namespace = kubernetes_namespace.wealthfolio.metadata[0].name
+    labels = {
+      "app" = "wealthfolio"
+    }
+  }
+
+  spec {
+    selector = {
+      app = "wealthfolio"
+    }
+    port {
+      name        = "http"
+      port        = 80
+      target_port = 8080
+    }
+  }
+}
+
+module "ingress" {
+  source          = "../../../modules/kubernetes/ingress_factory"
+  namespace       = kubernetes_namespace.wealthfolio.metadata[0].name
+  name            = "wealthfolio"
+  tls_secret_name = var.tls_secret_name
+  protected       = true
+}