variable "tls_secret_name" {}
variable "tier" { type = string }

resource "kubernetes_deployment" "flaresolverr" {
  metadata {
    name      = "flaresolverr"
    namespace = "servarr"
    labels = {
      app  = "flaresolverr"
      tier = var.tier
    }
    annotations = {
      "reloader.stakater.com/search" = "true"
    }
  }
  spec {
    replicas = 0 # Scaled down — headless Chrome with no effective resource limits causes node OOM
    selector {
      match_labels = {
        app = "flaresolverr"
      }
    }
    template {
      metadata {
        labels = {
          app = "flaresolverr"
        }
      }
      spec {
        container {
          image = "ghcr.io/flaresolverr/flaresolverr:latest"
          name  = "flaresolverr"

          resources {
            requests = {
              cpu    = "10m"
              memory = "512Mi"
            }
            limits = {
              memory = "512Mi"
            }
          }
          port {
            container_port = 8191
          }
        }
      }
    }
  }
}

resource "kubernetes_service" "flaresolverr" {
  metadata {
    name      = "flaresolverr"
    namespace = "servarr"
    labels = {
      app = "flaresolverr"
    }
  }

  spec {
    selector = {
      app = "flaresolverr"
    }
    port {
      name        = "http"
      target_port = 8191
      port        = 80
    }
  }
}

module "ingress" {
  source          = "../../../modules/kubernetes/ingress_factory"
  namespace       = "servarr"
  name            = "flaresolverr"
  tls_secret_name = var.tls_secret_name
  protected       = true
  extra_annotations = {
    "gethomepage.dev/enabled"      = "true"
    "gethomepage.dev/name"         = "FlareSolverr"
    "gethomepage.dev/description"  = "Captcha solver proxy"
    "gethomepage.dev/icon"         = "flaresolverr.png"
    "gethomepage.dev/group"        = "Media & Entertainment"
    "gethomepage.dev/pod-selector" = ""
  }
}