23019da8e5
After node2 OOM incident, right-size memory across the cluster by setting requests=limits based on max_over_time(container_memory_working_set_bytes[7d]) with 1.3x headroom. Eliminates ~37Gi overcommit gap. Categories: - Safe equalization (50 containers): set req=lim where max7d well within target - Limit increases (8 containers): raise limits for services spiking above current - No Prometheus data (12 containers): conservatively set lim=req - Exception: nextcloud keeps req=256Mi/lim=8Gi due to Apache memory spikes Also increased dbaas namespace quota from 12Gi to 16Gi to accommodate mysql 4Gi limits across 3 replicas.
128 lines
3 KiB
HCL
128 lines
3 KiB
HCL
variable "tls_secret_name" {}
|
||
variable "tier" { type = string }
|
||
variable "aiostreams_database_connection_string" { type = string }
|
||
variable "nfs_server" { type = string }
|
||
|
||
resource "kubernetes_namespace" "aiostreams" {
|
||
metadata {
|
||
name = "aiostreams"
|
||
labels = {
|
||
"istio-injection" : "disabled"
|
||
}
|
||
}
|
||
}
|
||
|
||
resource "random_id" "secret_key" {
|
||
byte_length = 32 # 32 bytes × 2 hex chars = 64 hex characters
|
||
}
|
||
|
||
module "nfs_data" {
|
||
source = "../../../modules/kubernetes/nfs_volume"
|
||
name = "aiostreams-data"
|
||
namespace = kubernetes_namespace.aiostreams.metadata[0].name
|
||
nfs_server = var.nfs_server
|
||
nfs_path = "/mnt/main/servarr/aiostreams"
|
||
}
|
||
|
||
resource "kubernetes_deployment" "aiostreams" {
|
||
metadata {
|
||
name = "aiostreams"
|
||
namespace = kubernetes_namespace.aiostreams.metadata[0].name
|
||
labels = {
|
||
app = "aiostreams"
|
||
tier = var.tier
|
||
}
|
||
}
|
||
spec {
|
||
replicas = 1
|
||
selector {
|
||
match_labels = {
|
||
app = "aiostreams"
|
||
}
|
||
}
|
||
template {
|
||
metadata {
|
||
labels = {
|
||
app = "aiostreams"
|
||
}
|
||
}
|
||
spec {
|
||
container {
|
||
image = "viren070/aiostreams:nightly"
|
||
name = "aiostreams"
|
||
port {
|
||
container_port = 3000
|
||
}
|
||
env {
|
||
name = "BASE_URL"
|
||
value = "https://aiostreams.viktorbarzin.me"
|
||
}
|
||
env {
|
||
name = "SECRET_KEY"
|
||
value = random_id.secret_key.hex
|
||
}
|
||
env {
|
||
name = "DATABASE_URI"
|
||
value = var.aiostreams_database_connection_string
|
||
}
|
||
volume_mount {
|
||
name = "data"
|
||
mount_path = "/app/data"
|
||
}
|
||
resources {
|
||
requests = {
|
||
cpu = "25m"
|
||
memory = "768Mi"
|
||
}
|
||
limits = {
|
||
memory = "768Mi"
|
||
}
|
||
}
|
||
}
|
||
volume {
|
||
name = "data"
|
||
persistent_volume_claim {
|
||
claim_name = module.nfs_data.claim_name
|
||
}
|
||
}
|
||
}
|
||
}
|
||
}
|
||
}
|
||
|
||
resource "kubernetes_service" "aiostreams" {
|
||
metadata {
|
||
name = "aiostreams"
|
||
namespace = kubernetes_namespace.aiostreams.metadata[0].name
|
||
labels = {
|
||
"app" = "aiostreams"
|
||
}
|
||
}
|
||
|
||
spec {
|
||
selector = {
|
||
app = "aiostreams"
|
||
}
|
||
port {
|
||
name = "http"
|
||
port = 80
|
||
target_port = 3000
|
||
}
|
||
}
|
||
}
|
||
|
||
module "ingress" {
|
||
source = "../../../modules/kubernetes/ingress_factory"
|
||
namespace = kubernetes_namespace.aiostreams.metadata[0].name
|
||
name = "aiostreams"
|
||
tls_secret_name = var.tls_secret_name
|
||
# protected = true
|
||
extra_annotations = {
|
||
"gethomepage.dev/enabled" = "true"
|
||
"gethomepage.dev/name" = "AIOStreams"
|
||
"gethomepage.dev/description" = "Streaming addon manager"
|
||
"gethomepage.dev/icon" = "stremio.png"
|
||
"gethomepage.dev/group" = "Media & Entertainment"
|
||
"gethomepage.dev/pod-selector" = ""
|
||
}
|
||
}
|