infra/stacks/onlyoffice/main.tf

variable "tls_secret_name" {
  type      = string
  sensitive = true
}
variable "nfs_server" { type = string }
variable "redis_host" { type = string }
variable "mysql_host" { type = string }

resource "kubernetes_namespace" "onlyoffice" {
  metadata {
    name = "onlyoffice"
    labels = {
      "istio-injection" : "disabled"
      tier                                    = local.tiers.edge
      "resource-governance/custom-limitrange" = "true"
      "resource-governance/custom-quota"      = "true"
      "keel.sh/enrolled" = "true"
    }
  }
  lifecycle {
    # KYVERNO_LIFECYCLE_V1: goldilocks-vpa-auto-mode ClusterPolicy stamps this label on every namespace
    ignore_changes = [metadata[0].labels["goldilocks.fairwinds.com/vpa-update-mode"]]
  }
}

resource "kubernetes_manifest" "external_secret" {
  manifest = {
    apiVersion = "external-secrets.io/v1beta1"
    kind       = "ExternalSecret"
    metadata = {
      name      = "onlyoffice-secrets"
      namespace = "onlyoffice"
    }
    spec = {
      refreshInterval = "15m"
      secretStoreRef = {
        name = "vault-kv"
        kind = "ClusterSecretStore"
      }
      target = {
        name = "onlyoffice-secrets"
      }
      dataFrom = [{
        extract = {
          key = "onlyoffice"
        }
      }]
    }
  }
  depends_on = [kubernetes_namespace.onlyoffice]
}

resource "kubernetes_limit_range" "onlyoffice" {
  metadata {
    name      = "onlyoffice-limits"
    namespace = kubernetes_namespace.onlyoffice.metadata[0].name
  }
  spec {
    limit {
      type = "Container"
      default = {
        memory = "256Mi"
      }
      default_request = {
        cpu    = "25m"
        memory = "64Mi"
      }
      max = {
        memory = "8Gi"
      }
    }
  }
}

resource "kubernetes_resource_quota" "onlyoffice" {
  metadata {
    name      = "onlyoffice-quota"
    namespace = kubernetes_namespace.onlyoffice.metadata[0].name
  }
  spec {
    hard = {
      "requests.cpu"    = "4"
      "requests.memory" = "4Gi"
      "limits.memory"   = "16Gi"
      pods              = "10"
    }
  }
}

module "tls_secret" {
  source          = "../../modules/kubernetes/setup_tls_secret"
  namespace       = kubernetes_namespace.onlyoffice.metadata[0].name
  tls_secret_name = var.tls_secret_name
}

module "nfs_data_host" {
  source       = "../../modules/kubernetes/nfs_volume"
  name         = "onlyoffice-data-host"
  namespace    = kubernetes_namespace.onlyoffice.metadata[0].name
  nfs_server   = var.nfs_server
  nfs_path     = "/srv/nfs/onlyoffice"
  storage      = "1Gi"
  access_modes = ["ReadWriteOnce"]
}

resource "kubernetes_deployment" "onlyoffice-document-server" {
  metadata {
    name      = "onlyoffice-document-server"
    namespace = kubernetes_namespace.onlyoffice.metadata[0].name
    labels = {
      app  = "onlyoffice-document-server"
      tier = local.tiers.edge
    }
    annotations = {
      "reloader.stakater.com/auto" = "true"
    }
  }
  spec {
    # TEMP-SCALEDOWN-2026-05-25-IO-STORM: scaled to 0 during cluster recovery.
    # Restore to 1 when cluster is fully stable. See post-mortem
    # docs/post-mortems/2026-05-25-immich-anca-elements-io-storm.md.
    replicas = 0
    strategy {
      type = "Recreate"
    }
    selector {
      match_labels = {
        app = "onlyoffice-document-server"
      }
    }
    template {
      metadata {
        labels = {
          app = "onlyoffice-document-server"
        }
        annotations = {
          "dependency.kyverno.io/wait-for" = "mysql.dbaas:3306,redis-master.redis:6379"
        }
      }
      spec {
        container {
          name  = "onlyoffice-document-server"
          image = "onlyoffice/documentserver:9.3.1"
          resources {
            requests = {
              cpu    = "100m"
              memory = "1536Mi"
            }
            limits = {
              memory = "1536Mi"
            }
          }
          port {
            name           = "http"
            container_port = 80
            protocol       = "TCP"
          }
          env {
            name  = "DB_TYPE"
            value = "mariadb"
          }
          env {
            name  = "DB_HOST"
            value = var.mysql_host
          }
          env {
            name  = "DB_PORT"
            value = 3306
          }
          env {
            name  = "DB_NAME"
            value = "onlyoffice"
          }
          env {
            name  = "DB_USER"
            value = "onlyoffice"
          }
          env {
            name = "DB_PWD"
            value_from {
              secret_key_ref {
                name = "onlyoffice-secrets"
                key  = "db_password"
              }
            }
          }
          env {
            name  = "REDIS_SERVER_HOST"
            value = var.redis_host
          }
          env {
            name  = "REDIS_SERVER_PORT"
            value = 6379
          }
          env {
            name = "JWT_SECRET"
            value_from {
              secret_key_ref {
                name = "onlyoffice-secrets"
                key  = "jwt_token"
              }
            }
          }

          volume_mount {
            name       = "data"
            mount_path = "/var/www/onlyoffice/Data"
          }
        }
        volume {
          name = "data"
          persistent_volume_claim {
            claim_name = module.nfs_data_host.claim_name
          }
        }
      }
    }
  }
  lifecycle {
    ignore_changes = [
      spec[0].template[0].spec[0].dns_config, # KYVERNO_LIFECYCLE_V1
      metadata[0].annotations["keel.sh/policy"],
      metadata[0].annotations["keel.sh/trigger"],
      metadata[0].annotations["keel.sh/pollSchedule"], # KYVERNO_LIFECYCLE_V2
    ]
  }
}

resource "kubernetes_service" "onlyoffice" {
  metadata {
    name      = "onlyoffice-document-server"
    namespace = kubernetes_namespace.onlyoffice.metadata[0].name
    labels = {
      "app" = "onlyoffice-document-server"
    }
  }

  spec {
    selector = {
      app = "onlyoffice-document-server"
    }
    port {
      port = "80"
    }
  }
}
module "ingress" {
  source = "../../modules/kubernetes/ingress_factory"
  # Iframe-loaded by Nextcloud with JWT-signed session tokens; OnlyOffice
  # validates the JWT itself. Authentik forward-auth would 302 the iframe
  # load if the browser doesn't already have an Authentik cookie, AND
  # OnlyOffice's server-to-server callback URLs (Nextcloud → OnlyOffice
  # for save events, etc.) run outside any browser session entirely.
  # The JWT is the auth gate.
  # auth = "none": Iframe loaded by Nextcloud with JWT-signed tokens; JWT is the auth gate; forward-auth breaks iframe + server-to-server callbacks.
  auth            = "none"
  dns_type        = "proxied"
  namespace       = kubernetes_namespace.onlyoffice.metadata[0].name
  name            = "onlyoffice"
  service_name    = "onlyoffice-document-server"
  tls_secret_name = var.tls_secret_name
  extra_annotations = {
    "gethomepage.dev/enabled"      = "true"
    "gethomepage.dev/name"         = "OnlyOffice"
    "gethomepage.dev/description"  = "Document editor"
    "gethomepage.dev/icon"         = "onlyoffice.png"
    "gethomepage.dev/group"        = "Other"
    "gethomepage.dev/pod-selector" = ""
  }
}

# CI retrigger 2026-05-16T13:42:57+00:00 — bulk enrollment apply (pipeline #689 killed)
# CI retrigger v2 2026-05-16T13:46:35+00:00