15b0b26a05
After node2 OOM incident, right-size memory across the cluster by setting requests=limits based on max_over_time(container_memory_working_set_bytes[7d]) with 1.3x headroom. Eliminates ~37Gi overcommit gap. Categories: - Safe equalization (50 containers): set req=lim where max7d well within target - Limit increases (8 containers): raise limits for services spiking above current - No Prometheus data (12 containers): conservatively set lim=req - Exception: nextcloud keeps req=256Mi/lim=8Gi due to Apache memory spikes Also increased dbaas namespace quota from 12Gi to 16Gi to accommodate mysql 4Gi limits across 3 replicas.
143 lines
3.3 KiB
HCL
143 lines
3.3 KiB
HCL
variable "tls_secret_name" {}
|
|
variable "tier" { type = string }
|
|
variable "k8s_ca_cert" {
|
|
type = string
|
|
default = ""
|
|
}
|
|
|
|
resource "kubernetes_namespace" "k8s_portal" {
|
|
metadata {
|
|
name = "k8s-portal"
|
|
labels = {
|
|
tier = var.tier
|
|
}
|
|
}
|
|
}
|
|
|
|
module "tls_secret" {
|
|
source = "../../../../modules/kubernetes/setup_tls_secret"
|
|
namespace = kubernetes_namespace.k8s_portal.metadata[0].name
|
|
tls_secret_name = var.tls_secret_name
|
|
}
|
|
|
|
resource "kubernetes_config_map" "k8s_portal_config" {
|
|
metadata {
|
|
name = "k8s-portal-config"
|
|
namespace = kubernetes_namespace.k8s_portal.metadata[0].name
|
|
}
|
|
|
|
data = {
|
|
"ca.crt" = var.k8s_ca_cert
|
|
}
|
|
}
|
|
|
|
resource "kubernetes_deployment" "k8s_portal" {
|
|
metadata {
|
|
name = "k8s-portal"
|
|
namespace = kubernetes_namespace.k8s_portal.metadata[0].name
|
|
labels = {
|
|
app = "k8s-portal"
|
|
tier = var.tier
|
|
}
|
|
}
|
|
|
|
spec {
|
|
replicas = 1
|
|
selector {
|
|
match_labels = {
|
|
app = "k8s-portal"
|
|
}
|
|
}
|
|
|
|
template {
|
|
metadata {
|
|
labels = {
|
|
app = "k8s-portal"
|
|
}
|
|
}
|
|
|
|
spec {
|
|
container {
|
|
name = "portal"
|
|
image = "viktorbarzin/k8s-portal:latest"
|
|
port {
|
|
container_port = 3000
|
|
}
|
|
|
|
volume_mount {
|
|
name = "config"
|
|
mount_path = "/config"
|
|
read_only = true
|
|
}
|
|
resources {
|
|
requests = {
|
|
cpu = "10m"
|
|
memory = "128Mi"
|
|
}
|
|
limits = {
|
|
memory = "128Mi"
|
|
}
|
|
}
|
|
}
|
|
|
|
volume {
|
|
name = "config"
|
|
config_map {
|
|
name = kubernetes_config_map.k8s_portal_config.metadata[0].name
|
|
}
|
|
}
|
|
dns_config {
|
|
option {
|
|
name = "ndots"
|
|
value = "2"
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
resource "kubernetes_service" "k8s_portal" {
|
|
metadata {
|
|
name = "k8s-portal"
|
|
namespace = kubernetes_namespace.k8s_portal.metadata[0].name
|
|
}
|
|
|
|
spec {
|
|
selector = {
|
|
app = "k8s-portal"
|
|
}
|
|
port {
|
|
port = 80
|
|
target_port = 3000
|
|
}
|
|
}
|
|
}
|
|
|
|
module "ingress" {
|
|
source = "../../../../modules/kubernetes/ingress_factory"
|
|
namespace = kubernetes_namespace.k8s_portal.metadata[0].name
|
|
name = "k8s-portal"
|
|
tls_secret_name = var.tls_secret_name
|
|
protected = true # Require Authentik login
|
|
extra_annotations = {
|
|
"gethomepage.dev/enabled" = "true"
|
|
"gethomepage.dev/name" = "K8s Portal"
|
|
"gethomepage.dev/description" = "Kubernetes portal"
|
|
"gethomepage.dev/icon" = "kubernetes.png"
|
|
"gethomepage.dev/group" = "Core Platform"
|
|
"gethomepage.dev/pod-selector" = ""
|
|
}
|
|
}
|
|
|
|
# Unprotected ingress for the setup script and agent endpoint (needs to be curl-able without auth)
|
|
module "ingress_setup_script" {
|
|
source = "../../../../modules/kubernetes/ingress_factory"
|
|
namespace = kubernetes_namespace.k8s_portal.metadata[0].name
|
|
name = "k8s-portal-setup"
|
|
host = "k8s-portal"
|
|
service_name = "k8s-portal"
|
|
ingress_path = ["/setup/script", "/agent"]
|
|
tls_secret_name = var.tls_secret_name
|
|
protected = false
|
|
}
|