e2d46ebd30
Frees a per-node SCSI-LUN slot on node6 (21->20). Volume holds only config.json (no embedded DB) -> NFS-safe. config pre-seeded to /srv/nfs/isponsorblocktv before cutover. RWO-destroy deadlock during apply (TF deleting the in-use old PVC before rolling the deployment) was broken by patching the deployment claim to the NFS PVC; TF reconciled to the same value.
101 lines
3.1 KiB
HCL
101 lines
3.1 KiB
HCL
variable "nfs_server" { type = string }
|
|
|
|
resource "kubernetes_namespace" "isponsorblocktv" {
|
|
metadata {
|
|
name = "isponsorblocktv"
|
|
labels = {
|
|
"istio-injection" : "disabled"
|
|
tier = local.tiers.edge
|
|
"keel.sh/enrolled" = "true"
|
|
}
|
|
}
|
|
lifecycle {
|
|
# KYVERNO_LIFECYCLE_V1: goldilocks-vpa-auto-mode ClusterPolicy stamps this label on every namespace
|
|
ignore_changes = [metadata[0].labels["goldilocks.fairwinds.com/vpa-update-mode"]]
|
|
}
|
|
}
|
|
# Before running, setup config using
|
|
# docker run --rm -it -v ./youtube:/app/data -e TERM=$TERM -e COLORTERM=$COLORTERM ghcr.io/dmunozv04/isponsorblocktv --setup
|
|
|
|
# Migrated proxmox-lvm -> NFS (2026-06-04) to free a per-node SCSI-LUN slot
|
|
# (node6 LUN-cap relief, beads code-dfjn). The volume holds only config.json
|
|
# (no embedded DB), so NFS is safe. Data pre-seeded to /srv/nfs/isponsorblocktv.
|
|
module "nfs_data" {
|
|
source = "../../modules/kubernetes/nfs_volume"
|
|
name = "isponsorblocktv-data"
|
|
namespace = kubernetes_namespace.isponsorblocktv.metadata[0].name
|
|
nfs_server = var.nfs_server
|
|
nfs_path = "/srv/nfs/isponsorblocktv"
|
|
storage = "1Gi"
|
|
}
|
|
|
|
# Mute and skip ads for vermont smart tv
|
|
resource "kubernetes_deployment" "isponsorblocktv-vermont" {
|
|
metadata {
|
|
name = "isponsorblocktv-vermont"
|
|
namespace = kubernetes_namespace.isponsorblocktv.metadata[0].name
|
|
labels = {
|
|
app = "isponsorblocktv-vermont"
|
|
tier = local.tiers.edge
|
|
}
|
|
}
|
|
spec {
|
|
replicas = 1
|
|
strategy {
|
|
type = "Recreate"
|
|
}
|
|
selector {
|
|
match_labels = {
|
|
app = "isponsorblocktv-vermont"
|
|
}
|
|
}
|
|
template {
|
|
metadata {
|
|
labels = {
|
|
app = "isponsorblocktv-vermont"
|
|
}
|
|
}
|
|
spec {
|
|
container {
|
|
image = "ghcr.io/dmunozv04/isponsorblocktv"
|
|
name = "isponsorblocktv-vermont"
|
|
volume_mount {
|
|
name = "data"
|
|
mount_path = "/app/data"
|
|
}
|
|
resources {
|
|
requests = {
|
|
cpu = "10m"
|
|
memory = "64Mi"
|
|
}
|
|
limits = {
|
|
memory = "64Mi"
|
|
}
|
|
}
|
|
}
|
|
volume {
|
|
name = "data"
|
|
persistent_volume_claim {
|
|
claim_name = module.nfs_data.claim_name
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
lifecycle {
|
|
ignore_changes = [
|
|
spec[0].template[0].spec[0].dns_config, # KYVERNO_LIFECYCLE_V1
|
|
metadata[0].annotations["keel.sh/policy"],
|
|
metadata[0].annotations["keel.sh/trigger"],
|
|
metadata[0].annotations["keel.sh/pollSchedule"], # KYVERNO_LIFECYCLE_V2
|
|
metadata[0].annotations["keel.sh/match-tag"],
|
|
spec[0].template[0].spec[0].container[0].image, # KEEL_IGNORE_IMAGE — Keel manages tag updates
|
|
metadata[0].annotations["kubernetes.io/change-cause"],
|
|
metadata[0].annotations["deployment.kubernetes.io/revision"],
|
|
spec[0].template[0].metadata[0].annotations["keel.sh/update-time"], # KEEL_LIFECYCLE_V1
|
|
]
|
|
}
|
|
}
|
|
|
|
# CI retrigger 2026-05-16T13:42:57+00:00 — bulk enrollment apply (pipeline #689 killed)
|
|
# CI retrigger v2 2026-05-16T13:46:35+00:00
|